home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / umich / falcon / programm.ing / nt_dsp1.lzh / NT_DSP1.MSA / FLOAT / FPSQRT.ASM < prev    next >
Assembly Source File  |  1989-01-24  |  3KB  |  88 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAIMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Last Update 5 Oct 87   Version 2.0
  7. ;
  8. fpsqrt  ident   2,0
  9. ;
  10. ; MOTOROLA DSP56000/1 FPLIB - VERSION 2
  11. ;
  12. ; FPSQRT - FLOATING POINT SQUARE ROOT SUBROUTINE
  13. ;
  14. ; Entry points: fsqrt_a R = square root(A)
  15. ;               fsqrt_x R = square root(X)
  16. ;
  17. ;       m = 24 bit mantissa (two's complement, normalized fraction)
  18. ;
  19. ;       e = 14 bit exponent (unsigned integer, biased by +8191)
  20. ;
  21. ; Input variables:
  22. ;
  23. ;   X   x1 = mx  (normalized)
  24. ;       x0 = ex
  25. ;
  26. ;   A   a2 = sign extension of ma
  27. ;       a1 = ma  (normalized)
  28. ;       a0 = zero
  29. ;
  30. ;       b2 = sign extension of ea (always zero)
  31. ;       b1 = ea
  32. ;       b0 = zero
  33. ;
  34. ; Output variables:
  35. ;
  36. ;   R   a2 = sign extension of mr
  37. ;       a1 = mr  (normalized)
  38. ;       a0 = zero
  39. ;
  40. ;       b2 = sign extension of er (always zero)
  41. ;       b1 = er
  42. ;       b0 = zero
  43. ;
  44. ; Error conditions:     Set CCR L=1 if input value is negative.  Result
  45. ;                       is set to floating point zero.  The CCR L bit
  46. ;                       remains set until cleared by the user.
  47. ;
  48. ; Assumes n0, m0, shift constant table and scaling modes
  49. ; initialized by previous call to the subroutine "fpinit".
  50. ;
  51. ; Alters Data ALU Registers
  52. ;       a2      a1      a0      a
  53. ;       b2      b1      b0      b
  54. ;       x1      x0      y1      y0
  55. ;
  56. ; Alters Address Registers
  57. ;       r0
  58. ;
  59. ; Alters Program Control Registers
  60. ;       pc      sr
  61. ;       la      lc
  62. ;       ssh     ssl     sp
  63. ;
  64. ; Uses 2 locations on System Stack
  65. ;
  66. ;
  67. fsqrt_x tfr     x0,b    x1,a            ;get mx,ex
  68. fsqrt_a tst     a       fp_space:fp_ebias,x0    ;check for negative input
  69.         jmi     under                   ;jump if negative, set L bit
  70.         jeq     done                    ;jump if zero
  71.         sub     x0,b                    ;remove ebias from ea
  72.         lsr     b       #<$40,y0        ;er' = ea / 2, get first guess
  73.         jcc     _sqrt1                  ;jump if er' even
  74.         asr     a       fp_space:fp_m1,x1       ;divide ma by 2, get -1
  75.         sub     x1,b                    ;increment er' by 1
  76. _sqrt1  add     x0,b    y0,x0           ;add ebias to er', save first temp
  77.         clr     b       b,r0            ;clear root, save er'
  78.         do      #23,_sqrt2              ;square all 23 bits
  79.         mac     -x0,x0,a        a,x1    ;square temp, save ma
  80.         tge     x0,b                    ;update root if correct guess
  81.         move    y0,a                    ;get guess bit
  82.         asr     a                       ;try next bit
  83.         add     b,a     a,y0            ;form root guess, save guess bit
  84.         tfr     x1,a    a,x0            ;get ma, save temp
  85. _sqrt2
  86.         tfr     b,a     r0,b            ;get root mr, er
  87.         rts
  88.